;
; Converts the Zhang & Pradhan (1997) Fe IV upsilon data to CHIANTI
; format.
;
; PRY 31-Aug-2009
;

read_elvlc,'fe_4.elvlc',l1,term,conf,ss,ll,jj,ecm,eryd,ecmth,erydth,ref

openr,lin,'table3',/get_lun

levs=intarr(8771*2)

str1=''
FOR i=0,145 DO readf,lin,str1

readf,lin,levs

llev=levs[indgen(8771)*2]
ulev=levs[indgen(8771)*2+1]

str={llev: 0, ulev: 0, ups: fltarr(20)}
outstr=replicate(str,8771)

outstr.llev=llev
outstr.ulev=ulev

temp=0.

ups=fltarr(8771)
FOR i=0,19 DO BEGIN
  readf,lin,format='(f8.0)',t
  temp=[temp,t]
  readf,lin,ups
 ;
  outstr[*].ups[i]=ups
ENDFOR

temp=temp[1:*]


free_lun,lin

k=where(outstr.llev LE 37 AND outstr.ulev LE 37,nk)
outstr=outstr[k]

openw,lout,'fe_4.upsdat',/get_lun
printf,lout,format='(i3)',20

FOR i=0,nk-1 DO BEGIN
  l1=outstr[i].llev
  l2=outstr[i].ulev
  de=abs(eryd[l2-1]-eryd[l1-1])
  printf,lout,format='(2i5,f10.6,20e10.3)',outstr[i].llev,outstr[i].ulev, $
         de, temp
  printf,lout,format='(2i5,f10.6,20e10.3)',outstr[i].llev,outstr[i].ulev, $
         0., outstr[i].ups
ENDFOR

printf,lout,' -1'
printf,lout,'%file:  fe_4.upsdat'
printf,lout,'%Prepared for the CHIANTI database by Peter Young, 31-Aug-2009'
printf,lout,'%Upsilons: Zhang, HL & Pradhan, AK 1997, A&AS, 126, 373'
printf,lout,'%Energies: Observed energies from .elvlc file.'
printf,lout,' -1'

free_lun,lout

END